import QtQuick
import Quickshell
import Quickshell.Wayland
import qs.modules.Services
import qs.modules.applets
import qs.settings

Variants {
    model: Quickshell.screens
    delegate: PanelWindow {
        required property ShellScreen modelData
	aboveWindows: true
        screen: modelData
        anchors {
            top: true
            left: true
            bottom: true
            right: true
        }
        exclusionMode: ExclusionMode.Ignore
        color: 'transparent'
        visible: WidgetTracker.current !== "" && WidgetTracker.screen === modelData
        WlrLayershell.keyboardFocus: visible ? WlrKeyboardFocus.Exclusive : WlrKeyboardFocus.None
        Item {
            anchors.fill: parent
            focus: true
            Keys.onEscapePressed: event => {
                WidgetTracker.close();
                event.accepted = true;
            }
	    VolPopup {
		z: 1
		visible: WidgetTracker.current === "volume"
		anchors.right: parent.right
		anchors.top: parent.top
		anchors.topMargin: Config.cfg.bar.floating ? Config.cfg.bar.height + 20 : Config.cfg.bar.height
		anchors.rightMargin: 10
		
	    }
	    WallPicker {
		z: 1
		anchors.bottom: parent.bottom
		anchors.left: parent.left
		anchors.right: parent.right
		anchors.margins: 20
		implicitWidth: 1000
		implicitHeight: 200
		visible: WidgetTracker.current === "wallpapers"
	    }
	    MouseArea {
		z: 0
		anchors.fill: parent
		acceptedButtons: Qt.LeftButton
		onClicked: WidgetTracker.close()
	    }
        }
    }
}