pragma ComponentBehavior: Bound
import Quickshell
import Quickshell.Services.SystemTray
import Quickshell.Widgets
import QtQuick
import QtQuick.Layouts
import qs
import qs.settings

Item {
    id: root
    visible: iconRepeater.count != 0
    Layout.fillHeight: true
    required property double moduleHeight
    implicitHeight: moduleHeight
    implicitWidth: iconlayout.implicitWidth

    RowLayout {
        id: iconlayout
        anchors.centerIn: root
        Repeater {
            id: iconRepeater
            model: SystemTray.items
            delegate: Rectangle {
                id: iconWrapper
                color: Colors.base01
                required property var modelData
                implicitWidth: root.moduleHeight + 8
                implicitHeight: root.moduleHeight
                radius: Config.rounding
                IconImage {
                    anchors.centerIn: parent
                    source: iconWrapper.modelData.icon
                    implicitSize: 16
                }
                QsMenuAnchor {
                    id: menu
                    anchor.item: iconWrapper
                    menu: iconWrapper.modelData.menu
                }
                MouseArea {
                        anchors.fill: parent
                    acceptedButtons: Qt.LeftButton | Qt.RightButton
                    onClicked: mouse => {
                        if (mouse.button == Qt.RightButton) {
                            menu.open();
                        }
                    }
                }
            }
        }
    }
}