import QtQuick
import QtQuick.Layouts
import Quickshell
import Quickshell.Wayland

import qs
import qs.settings

Variants {
    model: Quickshell.screens
    delegate: WlrLayershell {
        id: root
        required property var modelData
        property double moduleHeight: implicitHeight - 10
        screen: modelData
        anchors {
            top: true
            left: true
            right: true
        }
        margins {
            top: Config.floating ? 10 : 0
            left: Config.floating ? 10 : 0
            right: Config.floating ? 10 : 0
        }
        color: 'transparent'
        implicitHeight: Config.barHeight
        layer: WlrLayer.Top
        Rectangle {
            id: container
            radius: Config.floating ? Config.rounding : 0
            color: Qt.rgba(Colors.base00.r, Colors.base00.g, Colors.base00.b, Config.opacity)
            anchors.fill: parent
            RowLayout {
                id: leftLayout
                spacing: 5
                anchors.left: parent.left
                anchors.verticalCenter: parent.verticalCenter
                anchors.leftMargin: Config.rounding == 0 ? Config.floating ? 0 : 10 : root.moduleHeight / 4
                Ws {
                    moduleHeight: root.moduleHeight
                    barScreen: root.modelData
                }
                ActiveWindow {
                    moduleHeight: root.moduleHeight
                }
            }

            RowLayout {
                id: centerLayout
                anchors.centerIn: parent
                spacing: 5
                Clock {
                    moduleHeight: root.moduleHeight
                }
            }

            RowLayout {
                id: rightLayout
                anchors.right: parent.right
                anchors.verticalCenter: parent.verticalCenter
                spacing: 5
                anchors.rightMargin: Config.rounding == 0 ? Config.floating ? 0 : 10 : root.moduleHeight / 4
                Mpris {
                    moduleHeight: root.moduleHeight
                }
                Bat {
                    moduleHeight: root.moduleHeight
                }
                Pw {
                    moduleHeight: root.moduleHeight
                }
                Tray {
                    moduleHeight: root.moduleHeight
                }
            }
        }
    }
}